Making Death Run map

[BraXi]

In this tutorial i will show you how to make map for Death Run.


=== SPAWN POINTS ===

First of all you need to know atleast mapping basics, you can find basic mapping tutorials You are not allowed to view links. Register or Login to view.
You are not allowed to view links. Register or Login to view.

Load your map in radiant, right click on grid and chose MP > MP_JUMPER_SPAWN, this is the spawn point used by DR to spawn jumpers, place about 32 spawns for them.



Now you need to make spawn for activator, right click on grid again and choose MP > MP_ACTIVATOR_SPAWN. Place it cloose to first trap's activation trigger.


At the end place one MP_GLOBAL_INTERMISSION spawn for spectator.
Now you're done with spawns but you still have to put activation triggers into the list so we could disable them in free run.

---

=== TRIGGERS & DISABLING TRAPS IN FREE RUN ===

Select activation trigger, hit N key to see its properties and copy given targetname, in this example i will use targetname: "trap1_trigger". Copy all targetnames to one file, we will need them now.



Open map script located in raw\maps\mp\mp_md_MYMAPNAME.gsc and now we will have to put these targetnames to the trigger list.
For this we will use function called addTriggerToList( name ), just paste this function at the end of your script.

PHP Code:

addTriggerToList( name )
{
    if( !isDefined( level.trapTriggers ) )
        level.trapTriggers = [];
    level.trapTriggers[level.trapTriggers.size] = getEnt( name, "targetname" );
} 


Each activation trigger must be written in this script otherwise mod will not disable traps in free run, place this code in your main() function:

PHP Code:

addTriggerToList( "trap1_trigger" );
addTriggerToList( "trap2_trigger" );
addTriggerToList( "trap3_trigger" ); 


After all edits code should look similar to this

PHP Code:

main()
{
    maps\mp\_load::main();

    level.fx_sparks = loadFx( "sparks/electric" );
    
    thread trap1();
    thread trap2();

    addTriggerToList( "trap1_trigger" );
    addTriggerToList( "trap2_trigger" );
}


addTriggerToList( name )
{
    if( !isDefined( level.trapTriggers ) )
        level.trapTriggers = [];
    level.trapTriggers[level.trapTriggers.size] = getEnt( name, "targetname" );
}


trap1()
{


    trig = getEnt( "trap1_trigger", "targetname" );
    panel = getEnt( "trap1_panel", "targetname" );
    brush = getEnt( "trap1_brush", "targetname" ); //entity has key: dmg value: 1000

    trig waittill( "trigger" );

    playFx( level.fx_sparks, panel.origin );
    brush moveZ( -600, 2 );
    brush playSound( "heavy_impact" );
}


trap2()
{
    fire = loadFx( "fire/someFireEffect" );

    trig = getEnt( "trap2_trigger", "targetname" );
    panel = getEnt( "trap2_panel", "targetname" );
    brush = getEnt( "trap2_brush", "targetname" ); // trigger_hurt, dmg:50

    brush.origin = brush.origin + (0,0,500);
    trig waittill( "trigger" );

    brush.origin = brush.origin - (0,0,500);

    playFx( level.fx_sparks, panel.origin );
    playFx( fire, brush.origin );

    wait 10;

    brush.origin = brush.origin + (0,0,500);
} 


---

=== TIME RECORD ===
(This functionality was added in Death Run version 1.2)

Now you should add end trigger to your map, it will notify mod that player finished map and the time record could work. For this place trigger_multiple with "targetname" set to "endmap_trig" at the end of your map.

---

=== MISC ===
(This functionality was added in Death Run version 1.2)

Since DR 1.2 You can mark Yourself as author of the map. Other players will see green icon similar to that one from mappers group on forum. Function arguments are as below and this function should be called in your main() before wait statements:
braxi\_common::mapAuthor( <name>, <last 8 digits from of guid> );
braxi\_common::mapAuthor( "BraXi", "123abc4d" );

Thats all, now make awesome map and throw us to knees.

[FR3AK]

Can i know,what's program called that with mapping , Please .I use one map/mod tool bugged maybe.Cause I cant launch.

[BraXi]

Go to <CoD4>/bin folder, there should be Radiant.

[FR3AK]

LoL i found it, ty very much.

[BraXi]

Updated for Death Run 1.2

[codglitcher00]

show us from the start

[Lossy]

(10-12-2012 02:45 AM)codglitcher00 Wrote: You are not allowed to view links. Register or Login to view.show us from the start

These are custom stuff made for deathrun only the rest is basic mapping which you can find around here or just google "CoD4 PC Basic mapping" Or go to You are not allowed to view links. Register or Login to view. they have a wiki page full of stuff: explains why braxi said at the top of the page "First of all you need to know atleast mapping basics, don't ask me for mapping tutorials because internet is full of them."

But it seems most people simply ignore this message and expect people here to guide them through it and take all the credit -_-

[BraXi]

(10-12-2012 02:45 AM)codglitcher00 Wrote: You are not allowed to view links. Register or Login to view.show us from the start

(01-01-2012 07:59 PM)BraXi Wrote: You are not allowed to view links. Register or Login to view.First of all you need to know atleast mapping basics, don't ask me for mapping tutorials because internet is full of them.

[HELLZ-Q8]

great braxi but This Thread Need More Things

[BraXi]

(12-22-2012 04:58 PM)HELLZ-Q8 Wrote: You are not allowed to view links. Register or Login to view.great braxi but This Thread Need More Things

It's enough for those who know GSC scripting, and those who don't, shouldn't make deathrun maps.